Примеры 28. Многочлены: Лестничные

>> << Ркв Ввд JfC LJ Фрз Слв Изм Рзг !: Помощь Словарь

28. Многочлены: Лестничные

Выражение вида */ x + s * i. n часто называется факториальной функцией, но, чтобы не путать с функцией ! , мы будем называть ее лестницей. Появляющиеся в ее определении множители, меняются с шагом s, будто ступеньки лестницы. Лестницы полезны в страховой деятельности и в разностном анализе.

Лестница представляет собой обобщение степени ^ (совпадает с ней при s=:0) и получается ее настройкой, как в ^!.s. Например:

   x + s * i. n  [ x=: 7 [ n=: 5 [ s=: _1
7 6 5 4 3

   (*/x + s * i. n);(x ^!.s n);(x ^!.0 n);(x^n)
+----+----+-----+-----+
|2520|2520|16807|16807|
+----+----+-----+-----+

Фраза +/c * x^!.s i.#c называется лестничным многочленом, также как +/c*x^i.#c называется степенным. Далее мы определим наречие P , производящее лестничный многочлен с заданной величиной шага s :

   P=: 1 : '+/@([ * ] ^!. x i.@#@[)"1 0'
   c=: 1 3 3 1 [ d=: 1 7 6 1 [ x=: 0 1 2 3 4
   (c p. x);(c 0 P x);(d _1 P x);(d p.!._1 x)
+-------------+-------------+-------------+-------------+
|1 8 27 64 125|1 8 27 64 125|1 8 27 64 125|1 8 27 64 125|
+-------------+-------------+-------------+-------------+

Как показано выше, лестничные многочлены эквивалентны обыкновенным с коэффициентами, выбранными подходящим образом. Более того, преобразование между этими двумя наборами коэффициентов можно осуществить при помощи матричного произведения:

   VM=: 1 : '[ ^!.x/ i.@#@]'
   TO=: 2 : '(x VM %. y VM)~ @i.@#'
   (0 TO _1 c) +/ . * c
1 7 6 1

Матрицы 0 TO _1 и _1 TO 0 обратны друг другу, и связаны с числами Стирлинга:

   (0 TO _1 i.5);(_1 TO 0 i.5)
+---------+------------+
|1 0 0 0 0|1 0  0  0  0|
|0 1 1 1 1|0 1 _1  2 _6|
|0 0 1 3 7|0 0  1 _3 11|
|0 0 0 1 6|0 0  0  1 _6|
|0 0 0 0 1|0 0  0  0  1|
+---------+------------+

Лестничный многочлен можно задать и непосредственно, настроив p.!.s .

>> << Ркв Ввд JfC LJ Фрз Слв Изм Рзг !: Помощь Словарь